// [[[ BEGIN Internal use only
begindefinefloor 254;
import = 1; // Cave Floor, splotchy green.
begindefinefloor 1;
fl_ed_which_sheet = 510;
fl_ed_which_icon = 16;

begindefinefloor 254;
import = 3; // Cave Floor, similar to floor #0
begindefinefloor 3;
fl_ed_which_sheet = 510;
fl_ed_which_icon = 17;

begindefinefloor 254;
import = 7; // Rough Cave Floor, similar to floor #4
begindefinefloor 7;
fl_ed_which_sheet = 510;
fl_ed_which_icon = 19;
// Internal use only END ]]]

// v1.0.5
// guard.txt
// Xoid (xoid@hotmail.com)

// Version History:
// v1.0.5 - Version by Xoid. Optimised, cleanned up.
// v1.0.4 - Abandoned version by Xoid. Didn't work.
// v1.0.3 - Version by Xoid. Altered so that blocked tiles can be placed as
// sparsely as possible. If blocked spaces ensure that an NPC cannot
// reach its destination, Jeff's inept coding causes major overhead.
// v1.0.2 - Minor revision by Xoid. Increments SDF, instead
// of setting it.
// v1.0.1 - Version by Xoid. Extra dialogue strings added.
// v1.0.0 - Version by Jeff Vogel. Original.

// A simple script for guards or soldiers in towns. Acts like a regular npc
// unless it's in a town the party has angered, in which case it goes mobile and
// hunts the party down.

// Memory Cells:
// 0 - Movement type.
// Legal values are: 0 - Wander randomly.
// 1 - Stand still until a target appears.
// 2 - Completely immobile, even if target appears.
// 3 - Walk to a waypoint and then back to start. Use
// memory cell 4 to indicate which waypoint.

// 1,2 - SDF coordinates. If these are left at 0 and 0, these memory cells are
// ignored. Otherwise, the SDF is incremented by 1 when this creature dies.

// 3 - Dialogue node to start with if talked to. if left at 0, this
// character doesn't talk.

// 4 - Waypoint. If memory 0 is != 3, then this value is ignored. Otherwise,
// it is the number of the waypoint the guard or soldier spends its time
// walking to and from.

// 5 - Maximum distance. If memory cell 0 is != 0, then this memory cell is
// ignored. Otherwise, this is the maximum distance the creature will roam
// from its starting position. If left at 0, this will default to 6 tiles.
//
// [* Making this script backwards compatible with v1.0.0 of basicnpc.txt]
begincreaturescript;

variables;
int i,is_a_guard,target;
int gone_to_waypoint = 0;
body;

beginstate INIT_STATE;
if ((get_memory_cell(0) == 2) && (town_status(-1) != 2))
set_mobility(ME,0);

if (get_memory_cell(5) == 0)
set_memory_cell(5,6);

set_char_script_mode(ME,1); // This NPC will act even at distance.

if (creature_type(ME) == 4) {
is_a_guard = 1;
set_summon_level(ME,1);
}
break;

beginstate DEAD_STATE;
// Increment the appropriate SDF for this NPC's death.
if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE;
// React if the town gone hostile.
if (town_status(current_town()) == 2) {
alert_char(ME);
set_mobility(ME,1);
}

// If I have a target, go attack it.
if (target_ok()) {
if (dist_to_char(get_target()) <= 16)
set_state(3);
else set_target(ME,-1);
}

// Look for a target, and attack it if its visible.
if (select_target(ME,8,0)) {
do_attack();
set_state(3);
}

// React if I have been attacked.
if (who_hit_me() >= 0) {
set_target(ME,who_hit_me());
do_attack();
set_state(3);
}

// If this NPC is hostile, then hunt the party down. Otherwise, just
// peacefully move around. Go back to start if I roam too far.
if (get_attitude(ME) >= 10)
approach_char(ME,random_party_member(),6);
else if (get_memory_cell(0) == 3) {
// March to waypoint and back.
if ((gone_to_waypoint == 0) && (get_ran(1,1,100) < 15)) {
if (approach_waypoint(ME,get_memory_cell(4),1))
gone_to_waypoint = 1;
}
else if ((gone_to_waypoint == 1) && (get_ran(1,1,100) < 15)) {
if (return_to_start(ME,1))
gone_to_waypoint = 0;
}
}
else {
if ((my_dist_from_start() >= get_memory_cell(5)) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0) && (get_memory_cell(0) != 3))) {
if (get_ran(1,1,100) < 40)
return_to_start(ME,1);
}
else if (get_memory_cell(0) == 0) {
fidget(ME,25);
}
}

// Text bubble code...
if (is_a_guard == TRUE) {
if ((is_combat() == 0) && (get_attitude(ME) < 10)) {
if (get_ran(1,1,100) < 6) {
i = get_ran(1,1,100);
if ((get_crime_level() > 0) && ((i < 6) || (i > 95)))
create_text_bubble("We're watching you... scum."); // Bless you, Morrowind.
else {
if (i < 26)
create_text_bubble("Evildoers will be punished.");
else if (i < 51)
create_text_bubble("Obey the law.");
else if (i < 76)
create_text_bubble("Stay in line.");
else
create_text_bubble("Watch it.");
}
}
}
}

// If I'm in combat and nothing above gave me something to do, stop now.
// Otherwise the script will keep running, eating up CPU cycles.
if (am_i_doing_action() == FALSE)
end_combat_turn();
break;

beginstate 3; // Attacking...
if (target_ok() == FALSE)
set_state(START_STATE);
do_attack();
break;

beginstate TALKING_STATE;
if (get_memory_cell(3) == 0) {
if (is_a_guard == TRUE) {
print_str_color("Talking: You make small talk with the guard, but you don't",2);
print_str_color(" learn anything new.",2);
}
else print_str_color("Talking: The soldier doesn't have anything to tell you.",2);
end();
}
else begin_talk_mode(get_memory_cell(3));
break;