// *************************************************************************************************
// Scenario script with two indepandant functions (one or both can be used)

// I.
// relocate characters at the end of a combat to the position they had at the beginning of the last turn
// of this combat, to avoid having them progressing and skipping a special encounter by repetitively
// starting-ending combat mode

// II.
// make switching party order by using the 'switch' buttons (under the portraits)
// - cost a turn without acting (monsters will act !)
// and/or
// - prevent this operation from physically reordering of the party
// (usual switch by moving on town ground is still possible, but then it's a real move)

// Uses flags (10 to 18, 29) for chars positions
// Uses flags (20 to 23, 29) for chars stat identification
// Uses flags (24, 29) for switching difficulty level : (it can be changed at any time during the game)
// 0 = normal, 1 = reordering, 2 = lost a turn, 3 = reordering + lost a turn
// *************************************************************************************************
// the constraint is that the start_state of the scenario script must be run each turn
// the code could also be executed from all (or some) town scripts in a state that is run each turn
// *************************************************************************************************

// SCENARIO SCRIPT

beginscenarioscript;

variables;
short result, done, count;
short i, j, k;

body;

// *************************************************************************************************
// START_SCEN_STATE
// *************************************************************************************************
beginstate START_SCEN_STATE;

// *************************************************************************************************
// init unique stats for switching, uses flags (20-23, 29) (not vital but avoid switch effects on scenario start)
// *************************************************************************************************
i = 0;
while (i <= 3) {
if (char_status(i) != 0) {
done = 0;
j = 0;
// try stat from Strength (0) to Pathfinder (24), use bought levels
while (j <= 24 && done == 0) {
result = get_stat_levels_bought(i, j) % 10;
done = 0;
k = 0;
while (k <= 3 && done < 3) {
// don't check against himself
if (k != i) {
if (char_status(k) == 0) done = done + 1;
else if (result != (get_stat_levels_bought(k, j) % 10)) done = done + 1;
}
k = k + 1;
}
if (done == 3) done = 1;
else done = 0;
j = j + 1;
}
j = j - 1;
// can't get a unique stat for char (i), drop it
if (done == 0) set_flag(20 + i, 29, 250);
// got a unique stat for char (i)
else set_flag(20 + i, 29, (j * 10) + result);
}
// set to default value for non-existing char (i)
else set_flag(20 + i, 29, 250);
i = i + 1;
}
// *************************************************************************************************
break;

// *************************************************************************************************
// LOAD_SCEN_STATE
// *************************************************************************************************
beginstate LOAD_SCEN_STATE;
break;

// *************************************************************************************************
// START_STATE
// *************************************************************************************************
beginstate START_STATE;
// this state has to be run each turn otherwise there will be no effect

// *************************************************************************************************
// first the code for relocating characters on combat end
// if used must be placed before the [refresh all chars positions] block, so in first place
// *************************************************************************************************
// check mode for relocation on combat end (0 : outdoor) (1 : town) (2 : combat) uses flags (10-18, 29)
// outdoor mode : just record
if (is_outdoor() == 1) {
set_flag(18, 29, 0);
}
// town mode : check for last turn mode, if it was combat relocate all chars
else if (is_town() == 1) {
// on combat end, in town mode only, relocate all chars to their position at the beginning of the last combat turn
// cannot easily get chars positions in the middle of a turn (except with all terrains checking in STEP_INTO_SPOT_STATE with char_on_me())
if (get_flag(18, 29) == 2) {
i = 0;
while (i <= 3) {
relocate_character(i, get_flag(10 + (2 * i), 29), get_flag(10 + (2 * i) + 1, 29));
i = i + 1;
}
// center screen on the first living, present, non-joined NPC character (the leader)
done = 0;
i = 0;
while (i <= 3 && done == 0) {
if (char_status(i) == 1) {
force_view_center(get_flag(10 + (2 * i), 29), get_flag(10 + (2 * i) + 1, 29));
done = 1;
}
i = i + 1;
}
force_instant_terrain_redraw();
print_str_color("End combat.", 4);
}
set_flag(18, 29, 1);
}
// combat mode : just record
else if (is_combat() == 1) {
set_flag(18, 29, 2);
}
// *************************************************************************************************


// *************************************************************************************************
// this code is common to both functions and must be between them
// *************************************************************************************************
// refresh all chars positions
i = 0;
while (i <= 3) {
set_flag(10 + (2 * i), 29, char_loc_x(i));
set_flag(10 + (2 * i) + 1, 29, char_loc_y(i));
i = i + 1;
}
// *************************************************************************************************


// *************************************************************************************************
// now the code for the 'switch' buttons control
// if used must be placed after the [refresh all chars positions] block, so in third place
// *************************************************************************************************
// the following flag can be set from anywhere to fit the situation (possible values 0 to 3)
set_flag(24, 29, 3);

// switching party order is reversed and/or paralyses whole party for one turn, not outdoor
// switching difficulty level : 0 = normal, 1 = reordering, 2 = lost a turn, 3 = reordering + lost a turn
// check stats for switching, uses flags (20-23, 29)
if (is_outdoor != 1) {
j = 0;
i = 0;
while (i <= 3 && j <= 2) {
count = get_flag(20 + i, 29);
// check all existing chars with their unique stat, if stats modulus 10 are !=, stats are !=
if (char_status(i) != 0 && count != 250) {
result = count % 10;
done = (count - result) / 10;
// if stat mismatch increase j by 1
if (get_stat_levels_bought(i, done) != result) j = j + 1;
}
i = i + 1;
}
// switching means at least two characters having their identification stat changed
if (j >= 2) {
// if flag(24, 29) = 1 or 3, physical reordering is not possible (reversed to last chars position)
if (get_flag(24, 29) == 1 || get_flag(24, 29) == 3) {
print_str_color("Reordering party...", 2);
i = 0;
while (i <= 3) {
if (char_status(i) == 1) {
count = get_flag(20 + i, 29);
result = count % 10;
done = (count - result) / 10;
// find the place the char had and replace it there
j = 0;
while (j <= 3) {
if (get_stat_levels_bought(j, done) == result) {
relocate_character(i, get_flag(10 + (2 * j), 29), get_flag(10 + (2 * j) + 1, 29));
}
j = j + 1;
}
}
i = i + 1;
}
// center screen on the first living, present, non-joined NPC character (the leader)
done = 0;
i = 0;
while (i <= 3 && done == 0) {
if (char_status(i) == 1) {
force_view_center(get_flag(10 + (2 * i), 29), get_flag(10 + (2 * i) + 1, 29));
done = 1;
}
i = i + 1;
}
force_instant_terrain_redraw();
}
// if flag(24, 29) = 2 or 3, paralyse all chars, and joined NPCs, one turn, unblockable
if (get_flag(24, 29) == 2 || get_flag(24, 29) == 3) {
if ((get_flag(24, 29) == 2) || is_town() == 1) {
print_str_color("You spend a turn reordering your party...", 3);
}
else {
print_str_color("You lost a turn trying to reorder your party...", 1);
}
i = 0;
while (i <= 5) {
set_char_status(i, 11, 1, 1, 0);
i = i + 1;
}
}
}
}
// refresh unique stats for switching, uses flags (20-23, 29)
i = 0;
while (i <= 3) {
if (char_status(i) != 0) {
done = 0;
j = 0;
// try stat from Strength (0) to Pathfinder (24), use bought levels
while (j <= 24 && done == 0) {
result = get_stat_levels_bought(i, j) % 10;
done = 0;
k = 0;
while (k <= 3 && done < 3) {
// don't check against himself
if (k != i) {
if (char_status(k) == 0) done = done + 1;
else if (result != (get_stat_levels_bought(k, j) % 10)) done = done + 1;
}
k = k + 1;
}
if (done == 3) done = 1;
else done = 0;
j = j + 1;
}
j = j - 1;
// can't get a unique stat for char (i), drop it
if (done == 0) set_flag(20 + i, 29, 250);
// got a unique stat for char (i)
else set_flag(20 + i, 29, (j * 10) + result);
}
// set to default value for non-existing char (i)
else set_flag(20 + i, 29, 250);
i = i + 1;
}
// *************************************************************************************************
break;