// Dehydration v1.2
// dehydration.txt
// Original version by Dahak.
// Revised thoroughly by Kelandon (tomwatts@berkeley.edu).
//
// This general script checks if the party has a special item, water, and does
// increasing amounts of damage to the party if they don't have it. This
// simulates thirst, as in a desert.
//
// This script should probably go in the scenario script and be run in the
// START_STATE, as depicted below.
//
// This script uses three SDFs. The default SDFs to use are (250,0), (250,1),
// and (250,2). If you want to use others, replace the values in the variables
// section. Several other values are editable, too.

variables;

// How many turns since the party last had water.
short last_drank;

// ALL OF THE FOLLOWING VARIABLES CAN BE EDITED TO SUIT WHATEVER YOUR SCENARIO'S
// SPECIFIC NEEDS ARE. CHANGE THEIR VALUES TO WHATEVER YOU LIKE.

// Change the following variable to whatever special item the water is.
short water = 0;

// Change the following variables to the coordinates of the SDFs keeping track
// of the time between water checks. This works by using the SDFs as a two-digit
// base-256 number. That is, the first SDF set to 5 and the second set to 2
// means that 2 * 256 + 5 (equalling 517) turns have passed since the last water
// check.
short sdf_x = 250;
short sdf_y1 = 0;
short sdf_y2 = 1;

// Change the following variables to the coordinates of the SDF keeping track
// of how many consecutive times the party has failed a water check.
short thirst_sdf_x = 0;
short thirst_sdf_y = 2;

// Change the following variable if you want the party to dehydrate slower or
// faster. This is the number of turns between each water check. NOTE: This can
// reasonably go up as high as sixty-five thousand. Any more than that, and you
// will need to add more SDFs to keep track of the ticks in between water
// checks.
short dehyd_speed = 500;

// Change the following variable if you want the party to die of dehydration
// slower or faster. This times dehyd_speed equals the number of turns without
// water after which the party will automatically die.
short dead_of_thirst = 8;

beginstate START_STATE;

// Figure out how many turns it has been since the party drank water and save
// that in last_drank.
last_drank = (get_flag(sdf_x,sdf_y2) * 256) + get_flag(sdf_x,sdf_y1);

// Check if enough time has passed since the last water check. If so, proceed.
if (last_drank >= dehyd_speed) {

// If the party has water, drink it.
if(has_special_item(water)) {
print_str("You drink some water.");
change_spec_item(water,-1);

// Reset all flags and counters.
set_flag(thirst_sdf_x,thirst_sdf_y,0);
set_flag(sdf_x,sdf_y2,0);
set_flag(sdf_x,sdf_y1,0);
}

// If the party doesn't have water, do other things.
else {
// Damage them based on how long they've been thirsty (recorded in the
// variable thirst_turns).
inc_flag(thirst_sdf_x,thirst_sdf_y,1);
damage_char(1000,(10 * get_flag(thirst_sdf_x,thirst_sdf_y)) + get_ran(1,0,9),4);
print_str ("You're thirsty!");

// Reset flags.
set_flag(sdf_x,sdf_y2,0);
set_flag(sdf_x,sdf_y1,0);

// Warn them if they're dying.
if (get_flag(thirst_sdf_x,thirst_sdf_y) == dead_of_thirst - 1)
print_str_color("YOU ARE NEAR DEATH. YOU NEED WATER.",1);

// If they are too thirsty, kill them.
if (get_flag(thirst_sdf_x,thirst_sdf_y) == dead_of_thirst) {
message_dialog("You die of thirst!","");
kill_char(1000,2,0);
}
}
}

// Increment the SDFs keeping track of time. This works differently outdoors
// because although ten ticks pass for every step, the START_STATE is only
// called once per step.
if (get_flag(sdf_x,sdf_y1) < 255 - (9 * is_outdoor()))
inc_flag(sdf_x,sdf_y1,1 + (9 * is_outdoor()));
else {
inc_flag(sdf_x,sdf_y2,1);
set_flag(sdf_x,sdf_y1,0);
}

break;